Cara Menampilkan Database Pada Listview VB6

ini adalah Tutorial lanjutan setelah artikel sebelumnya Cara menampilkan Database pada Textbox, Baiklah langsung saja, untuk mengikuti Tutorial kali ini anda butuh membuat koneksi, lihat di Cara membuat koneksi Database ke VB6. untuk menampilkan data pada database ke Listview anda butuh listview control. pada tampilan awal VB6 control Listview belum ditampilkan cara menampilkannya adalah :

klik menu Project > Components (ctrl + T) : pilih dan centang Microsoft Windows Common Control 6.0(SP6). Drag control Listview ke form beri nama "LV" :

buka kode pada Form dan Buatlah Procedure untuk Set Listview dibawah ini.

Public Sub SetLV()
With LV
    .View = lvwReport
    .GridLines = True
    .MultiSelect = True
    .FullRowSelect = True
    .HotTracking = True
    .HoverSelection = True
    ' tambahkan kolom2 ke, , Judul,lebar,aligment
    .ColumnHeaders.Add 1, , "No", 750
    .ColumnHeaders.Add 2, , "Kode Barang", 1250
    .ColumnHeaders.Add 3, , "Nama Barang", 2500
    .ColumnHeaders.Add 4, , "Harga Beli", 1500, 1
    .ColumnHeaders.Add 5, , "Harga Jual", 1500, 1
    .ColumnHeaders.Add 6, , "Stok", 750
    .ColumnHeaders.Add 7, , "Satuan", 1000
    .Width = 9350
End With
End Sub

Penjelasan : Pulbic Sub SetLV() adalah nama procedure untuk set Listview, With LV > maksudnya dengan Control Listview (LV adalah nama Listview) jika nama listview tidak diganti berarti namanya "ListView1". kode yang berwarna kuning adalah Setting Pengaturan Listview > Untuk menambahkan Kolom-kolom pada Listview ".ColumnHeader.Add kolom ke? , ,"nama kolom", Lebar Kolom, aligmnet(kosong / 0> rata kiri, 1> rata kanan, 2> tengah. ".width" adalah lebar listview.

Selanjutnya untuk mengisi datanya ke Listview :

Public Sub TplGrid()
    Dim Lst As ListItem, nmr As Integer
    With rs
    LV.ListItems.Clear 'Bersihkan Listview
    Do While Not rs.EOF
    Set Lst = LV.ListItems.Add
    nmr = nmr + 1
    Lst.Text = nmr 'isi kolom 1 dng nmr
    Lst.SubItems(1) = rs!KodeBrg 'isi Kol 2 dng Kode Barang
    Lst.SubItems(2) = rs!NamaBrg 'kol 3 dng nma
    Lst.SubItems(3) = Format(rs!HBeli, "#,##0") 'kol 4 Hbeli
    Lst.SubItems(4) = Format(rs!Hjual, "#,##0") 'kol 5 Hjual
    Lst.SubItems(5) = rs!Stok 'kol 6 Stok
    Lst.SubItems(6) = rs!Satuan 'kol 7 satuan
    rs.MoveNext 'gerakan kursor de data berikutnya
    Loop
    End With
   
End Sub

Penjelasan : diatas adalah Procedure Tampil data ke Listview. Lst, dan nmr digunakan untuk mengisi data dan untuk menulis nomor. with rs (RS adalah Variable Recordset, saya buat di modul)  lihat Cara membuat koneksi Database ke VB6 Do while Not RS.EOF maksudnya lakukan selama kode tidak berada pada akhir data, Set Lst = LV.ListItem, adalah set variable Lst untuk Isi Listview, Lst.Text = kolom Pertama diisi dengan Nomor. Selanjutnya kolom-kolom berikutnya, diisi dengan data dari database. "rs!Kodebrg" rs nama variable Recordset dan kodebr nama field database. pada kolom 4 dan 5 berisi angka bisa diformat agar memiliki tanda pemisah.

Kode Pada FormLoad :

Private Sub Form_Load()
Call SetLV
If cn.State <> 1 Then KoneksiDB
  
rs.Open "Select * from Barang Order By KodeBrg", cn
Call TplGrid
Set rs = Nothing

End Sub

Penjelasan : Ini adalah kode pada FormLoad, call SetLV digunakan untuk memanggil procedure SetListview KoneksiDB untuk memanggil Koneksi, rs.Open adalah Perintah buka Recordset "Select * from nama tabel", cn adalah variable koneksi pada modul. call TplGrid digunakan untuk memanggil procedure mengisi data dari database ke Listview, Set rs=Nothing digunakan untuk mengosongkan Recordset. Selesai

Tampilan pada Saat dijalankan :

Tunggu Tutorial selanjutnya mengenai VB6.

Terimakasih, mohon maaf jika terdapat banyak kesalahan, semoga bermanfaat.



dsdsd